" Vim compiler file
" Compiler:     Inform
" Maintainer:   David K. Gerry	<gerrydk@comcast.net>
" Last Change:  2003 Aug 13

if exists("current_compiler")
  finish
endif
let current_compiler = 'inform'

" Setup the buffer makeprg
let infprg = 'inform'

if exists('g:inform_prg')
	let infprg = g:inform_prg
end

if exists('g:inform_icl')
	if exists('g:inform_icl_quote') && g:inform_icl_quote
		let infprg = infprg . " '(" . g:inform_icl . ")'"
	else
		let infprg = infprg . ' (' . g:inform_icl . ')'
	end
end

if exists('g:inform_args')
	let infprg = infprg . ' ' . g:inform_args
end

let &l:makeprg = infprg . ' $* %'

" Error file format for all error styles -E0 -E1 -E2 -c
" and bad ommand line switches
setlocal errorformat+=
	\Switch\ %m,
	\\"<before\ compilation>\"\\,\ line\ %l:\ Fatal\ error:\ %m,
	\%E\"%f\"\\,\ line\ %l:\ Fatal\ error:\ %m,%+C>\ %m,
	\%E\"%f\"\\,\ line\ %l:\ Error:\ %m,%+C>\ %m,
	\%W\"%f\"\\,\ line\ %l:\ Warning:\ %m,%+C>\ %m,
	\<before\ compilation>(%l):\ Fatal\ error:\ %m,
	\%E%f(%l):\ Fatal\ error:\ %m,%+C>\ %m,
	\%E%f(%l):\ Error:\ %m,%+C>\ %m,
	\%W%f(%l):\ Warning:\ %m,%+C>\ %m,
	\File\ \"<before\ compilation>\";\ Line\ %l\	#\ Fatal\ error:\ %m,
	\%EFile\ \"%f\";\ Line\ %l\	#\ Fatal\ error:\ %m,%+C>\ %m,
	\%EFile\ \"%f\";\ Line\ %l\	#\ Error:\ %m,%+C>\ %m,
	\%WFile\ \"%f\";\ Line\ %l\	#\ Warning:\ %m,%+C>\ %m

" cleanup
unlet infprg